rdos/kernel/fcb.asm

; diskbuf needs to be defined

; User-accessible part of FCB (12 bytes)
fcb_drv:   equ 0  ; 1 byte, 1=A: 2=B: 3=C:
fcb_fn:    equ 1  ; 8 bytes
fcb_ext:   equ 9  ; 3 bytes

; Drive & FS data (6 bytes)
fcb_spt:   equ 12 ; byte    sectors per track
fcb_nos:   equ 13 ; byte    number of sides/heads
fcb_ss:    equ 14 ; byte    sector size: 0=128, 1=256, 2=512, ...
fcb_cs:    equ 15 ; byte    cluster size: 0=128, 1=256, 2=512, ...
fcb_co:    equ 16 ; word    start sector for theoretical cluster 0

; Read/Write pointer (6 bytes)
fcb_left:  equ 18 ; word    number of bytes left to read from diskbuf
fcb_off:   equ 20 ; dword   offset in disk (not in file)

; Link to directory item (4 bytes)
fcb_ds:    equ 24 ; dword   offset of directory item

fcb_end:   equ 32

fcb_open_rootdir:
  mov dl, 0x01
  mov [bx], dl
  dec dl

  ; Setup default data
  ; Default 2 heads, 9 sectors
  mov word [bx+fcb_spt], 0x0209
  xor ax, ax
  lea di, [bx+fcb_ss]
  ; Sector & Cluster size 128 bytes
  mov cx, (fcb_end - fcb_ss)
  rep stosb

  ; load first sector
  call drive_read

  ; copy sector size
  mov ax, [diskbuf + 0x0B]
  ; ... save as number of valid bytes in diskbuf
  mov WORD [bx+fcb_left], ax
  call log2
  sub ax, 7
  ; ... save as sector size
  mov byte [bx+fcb_ss], al

  ; copy cluster size
  xor ah, ah
  mov al, [diskbuf + 0x0D]
  call log2
  add al, [bx+fcb_ss]
  mov byte [bx+fcb_cs], al

  ; copy sectors per track
  mov al, [diskbuf + 0x18]
  mov byte [bx+fcb_spt], al

  ; copy number of heads/sides
  mov al, [diskbuf + 0x1A]
  mov byte [bx+fcb_nos], al

  ret

fcb_get_sector_mask:
  push cx
  xor ax, ax
  not ax
  mov cl, [bx+fcb_ss]
  add cl, 7
  shl ax, cl
  pop cx
  ret

fcb_getc:
  push bx
  call fcb_get_sector_mask
  not ax
  and ax, [bx+fcb_off]
  xchg ax, bx
  add bx, diskbuf
  mov al, [bx]
  pop bx
  add word [bx+fcb_off], 1
  adc word [bx+fcb_off+2], 0
  dec word [bx+fcb_left]
  ret