91 lines
2.0 KiB
Perl
91 lines
2.0 KiB
Perl
package PoorBooru::API::V0::Controller::Tags;
|
|
use v5.36;
|
|
use strict;
|
|
use warnings;
|
|
|
|
use Mojo::Base "Mojolicious::Controller";
|
|
|
|
my $MEDIA_SEARCH_OPTS = {
|
|
order_by => { -desc => "media_id" },
|
|
rows => 5,
|
|
};
|
|
my $TAGS_COUNT_VIEW_SEARCH_OPTS = {
|
|
order_by => { -desc => "count" },
|
|
rows => 5,
|
|
};
|
|
|
|
sub _pager_links ($c, $pager)
|
|
{
|
|
+{ map +( $_ => ($pager->$_ and
|
|
$c->url_with->query({page => $pager->$_})) ),
|
|
qw(first_page previous_page current_page next_page last_page) }
|
|
}
|
|
|
|
sub list ($self)
|
|
{
|
|
my $v = $self->validation;
|
|
my $page = $v->optional("page")->num(1, undef)->param // 1;
|
|
|
|
return $self->render(
|
|
json => {error => "Invalid page number"},
|
|
status => 400,
|
|
) if $v->has_error;
|
|
|
|
my $paged_tags = $self->schema->resultset("TagCountView")
|
|
->search(undef, $TAGS_COUNT_VIEW_SEARCH_OPTS)->page($page);
|
|
my @tags = map +{
|
|
id => $_->tag_id,
|
|
name => $_->name,
|
|
count => $_->count,
|
|
}, $paged_tags->all;
|
|
|
|
return $self->render(json => {
|
|
pager => _pager_links($self, $paged_tags->pager),
|
|
tags => \@tags,
|
|
});
|
|
};
|
|
|
|
sub show ($self)
|
|
{
|
|
my $v = $self->validation;
|
|
my $page = $v->optional("page")->num(1, undef)->param // 1;
|
|
|
|
return $self->render(
|
|
json => {error => "Invalid page number"},
|
|
status => 400,
|
|
) if $v->has_error;
|
|
|
|
my $tag_id_or_name = $self->stash("tag_id_or_name");
|
|
|
|
my @search;
|
|
if ($tag_id_or_name =~ /^[1-9][0-9]*$/) {
|
|
push @search, { tag_id => $tag_id_or_name };
|
|
} else {
|
|
push @search, { name => $tag_id_or_name };
|
|
}
|
|
|
|
my $tag = $self->schema->resultset("Tag")->single(\@search);
|
|
|
|
return $self->render(
|
|
json => {error => "Tag not found"},
|
|
status => 404,
|
|
) if !defined($tag);
|
|
|
|
my $paged_media = $self->schema->resultset("TaggedMediaView")
|
|
->search({ tag_id => $tag->tag_id }, $MEDIA_SEARCH_OPTS)
|
|
->page($page);
|
|
my @media = map +{
|
|
media_id => $_->media_id,
|
|
seaweedfs_fid => $_->media_seaweedfs_fid,
|
|
}, $paged_media->all;
|
|
|
|
return $self->render(json => {
|
|
id => $tag->tag_id,
|
|
name => $tag->name,
|
|
pager => _pager_links($self, $paged_media->pager),
|
|
media => \@media,
|
|
});
|
|
};
|
|
|
|
1;
|