141 lines
3.3 KiB
Perl
141 lines
3.3 KiB
Perl
package PoorBooru::API::V0;
|
|
use Dancer2;
|
|
use Dancer2::Plugin::DBIC;
|
|
|
|
our $VERSION = v0;
|
|
|
|
set serializer => "JSON";
|
|
|
|
use constant {
|
|
ROUTES => [
|
|
{ path => "/meta", verb => "GET" },
|
|
{ path => "/tags", verb => "GET" },
|
|
{ path => "/tags", verb => "POST" },
|
|
{ path => "/tag/:tag_id_or_name", verb => "GET" },
|
|
{ path => "/media/:media_id", verb => "GET" },
|
|
{ path => "/download/:media_id", verb => "GET" },
|
|
{ path => "/random", verb => "GET" },
|
|
],
|
|
|
|
DEFAULT_CONTENT_TYPE => "application/json",
|
|
ROWS_PER_PAGE => 20,
|
|
};
|
|
|
|
my $TAG_NAME_RE = qr/^[0-9]*[A-Z_a-z][0-9A-Z_a-z]*$/;
|
|
|
|
sub mkpager ($)
|
|
{
|
|
my $pager = $_[0]->pager;
|
|
return {
|
|
first => $pager->first_page,
|
|
prev => $pager->previous_page,
|
|
cur => $pager->current_page,
|
|
next => $pager->next_page,
|
|
last => $pager->last_page,
|
|
};
|
|
}
|
|
|
|
get "/meta" => sub {
|
|
return ROUTES;
|
|
};
|
|
|
|
get "/tags" => sub {
|
|
my @tags = map +( {
|
|
id => $_->tag_id,
|
|
name => $_->name,
|
|
count => $_->count,
|
|
} ), schema("default")->resultset("TagsCountView")->all;
|
|
|
|
return \@tags;
|
|
};
|
|
|
|
post "/tags" => sub {
|
|
my $tag_name = body_parameters->get("name");
|
|
send_error("Invalid tag name", 404) if $tag_name !~ $TAG_NAME_RE;
|
|
|
|
my $tag;
|
|
eval {
|
|
$tag = schema("default")->resultset("Tag")
|
|
->create({ name => $tag_name });
|
|
} or send_error("Tag exists", 409);
|
|
|
|
return {
|
|
id => $tag->tag_id,
|
|
name => $tag->name,
|
|
};
|
|
};
|
|
|
|
get "/tag/:tag_id_or_name" => sub {
|
|
my ($tag, $tag_rset, @media);
|
|
my $tag_id_or_name = route_parameters->get("tag_id_or_name");
|
|
|
|
$tag_rset = schema("default")->resultset("Tag");
|
|
$tag = $tag_rset->single({ tag_id => $tag_id_or_name }) //
|
|
$tag_rset->single({ name => $tag_id_or_name });
|
|
|
|
send_error("Tag not found", 404) if !defined($tag);
|
|
|
|
@media = map { $_->media_id } schema("default")->resultset("MediaTag")
|
|
->search({ tag_id => $tag->tag_id })->all;
|
|
|
|
return {
|
|
id => $tag->tag_id,
|
|
name => $tag->name,
|
|
media => \@media,
|
|
};
|
|
};
|
|
|
|
get "/media" => sub {
|
|
my $page = query_parameters->get("page") // 1;
|
|
send_error("Invalid page number", 400) if $page !~ /^[1-9][0-9]*$/;
|
|
|
|
my $paged_media = schema("default")->resultset("Media")
|
|
->search({}, { order_by => "upload_date", rows => ROWS_PER_PAGE })
|
|
->page($page);
|
|
|
|
my @media = map { $_->media_id } $paged_media->all;
|
|
|
|
return {
|
|
pager => mkpager($paged_media),
|
|
media => \@media,
|
|
};
|
|
};
|
|
|
|
get "/media/:media_id" => sub {
|
|
my $media = schema("default")->resultset("Media")
|
|
->single({ media_id => route_parameters->get("media_id") });
|
|
|
|
send_error("Media not found", 404) if !defined($media);
|
|
|
|
return {
|
|
id => $media->media_id,
|
|
filename => $media->filename,
|
|
size => length($media->content),
|
|
download_path => "/download/" . $media->media_id,
|
|
};
|
|
};
|
|
|
|
get "/download/:media_id" => sub {
|
|
my $media = schema("default")->resultset("Media")
|
|
->single({ media_id => route_parameters->get("media_id") });
|
|
|
|
send_error("Media not found", 404) if !defined($media);
|
|
|
|
send_file(
|
|
\$media->content,
|
|
content_type => $media->content_type // DEFAULT_CONTENT_TYPE,
|
|
filename => $media->filename,
|
|
);
|
|
};
|
|
|
|
get "/random" => sub {
|
|
my $media = schema("default")->resultset("Media")
|
|
->search({}, { order_by => \"random()", limit => 1 })->single;
|
|
|
|
send_error("Media not found", 404) if !defined($media);
|
|
|
|
forward "/media/" . $media->media_id;
|
|
};
|
|
|
|
true;
|