package PoorBooru::Backend::Controller::Media;
use v5.36;
use strict;
use warnings;

use Mojo::Base "Mojolicious::Controller";
use Mojo::JSON qw(decode_json);

sub list ($self)
{
	my $v = $self->validation;
	my $page = $v->optional("page")->num(1, undef)->param // 1;

	return $self->render(
		status => 404,
	) if $v->has_error;

	my $poorbooru_api = $self->config("poorbooru_api");
	my $res = $self->ua->get("$poorbooru_api/media?page=$page")->result;

	return $self->render(status => $res->code) if $res->is_error;

	$self->title("Pooru~");
	my @media = map +{
		media_link => $self->url_for("media_show", media_id => $_->{media_id}),
		media_src  => $self->seaweed->url_for($_->{seaweedfs_fid}),
	}, $res->json->{media}->@*;

	return $self->render(
		template => "gallery",
		media    => [ @media ],
		pager    => { $self->pager_links($res->json->{pager}) },
	);
};

sub show ($self)
{
	my $v = $self->validation;
	my $page = $v->optional("page")->num(1, undef)->param // 1;

	return $self->render(status => 404) if $v->has_error;

	my $media_id = $self->stash("media_id");
	my $poorbooru_api = $self->config("poorbooru_api");
	my $res = $self->ua->get("$poorbooru_api/media/$media_id")
	    ->result;
	return $self->render(status => $res->code) if $res->is_error;

	my $media = $res->json;
	$media->{download} = $self->seaweed->url_for($media->{download});

	$res = $self->ua->get("$poorbooru_api/media/tags/$media_id?page=$page")
	    ->result;
	my $tags = $res->json->{tags};

	return $self->render(status => $res->code) if $res->is_error;

	return $self->render(
		template => "media",
		media    => $media,
		tags     => $tags,
		pager    => { $self->pager_links($res->json->{pager}) },
	);
};

1;